Introducción
Este artículo utiliza la placa NodeMCU (ESP8266) y el sensor de temperatura y humedad SHTC3 para conectarse a la plataforma de Internet de las Cosas (IoT) de Alibaba Cloud y subir los datos de temperatura y humedad leídos. Se lee la temperatura y la humedad cada segundo, y se sube cada 30 segundos el promedio de los datos obtenidos durante ese período. Puedes modificar el programa para usar otros sensores de temperatura y humedad. Este programa se desarrolló utilizando Arduino IDE.
Programa para leer datos de sensores DHT11 y DHT22: https://blog.zeruns.com/archives/527.html
Guía para configurar el entorno de desarrollo ESP8266: https://blog.zeruns.com/archives/526.html
Conecte el pin SDA del SHTC3 al pin D5 de NodeMCU y el pin SCL al pin D6 de NodeMCU.
Configuración de la plataforma IoT
Primero, registre una cuenta en Alibaba Cloud y active la plataforma IoT: https://www.aliyun.com/product/iot?source=5176.11533457&userCode=jdjc69nf&type=copy
Luego, abra la consola de la plataforma IoT: https://iot.console.aliyun.com/product
A continuación, siga las instrucciones de la imagen para crear un producto.
Siga las instrucciones de la imagen para agregar un dispositivo.
Código fuente del programa
Primero, instale las bibliotecas PubSubClient, ArduinoJson y SparkFun SHTC3.
Luego, modifique el archivo PubSubClient.h según las instrucciones a continuación.
Modifique los parámetros según las indicaciones en el código.
#include <ESP8266WiFi.h>
/* Requiere PubSubClient 2.4.0 */
#include <PubSubClient.h>
/* Requiere ArduinoJson 5.13.4 */
#include <ArduinoJson.h>
#include <SparkFun_SHTC3.h>
/* Conecte su SSID y contraseña de WiFi */
#define WIFI_SSID "SSID del router"
#define WIFI_PASSWD "contraseña"
/* Información de tripleta del dispositivo */
#define PRODUCT_KEY "PRODUCT_KEY del dispositivo"
#define DEVICE_NAME "reemplace DEVICE_NAME"
#define DEVICE_SECRET "reemplace DEVICE_SECRET"
#define REGION_ID "cn-shanghai"
/* Dominio y puerto del entorno en línea, no se deben modificar */
#define MQTT_SERVER PRODUCT_KEY ".iot-as-mqtt." REGION_ID ".aliyuncs.com"
#define MQTT_PORT 1883
#define MQTT_USRNAME DEVICE_NAME "&" PRODUCT_KEY
#define CLIENT_ID "ESP8266|securemode=3,timestamp=1234567890,signmethod=hmacsha1|"
// Herramienta de cifrado: http://iot-face.oss-cn-shanghai.aliyuncs.com/tools.htm para generar la contraseña
// Tutorial de contraseña: https://www.yuque.com/cloud-dev/iot-tech/mebm5g
#define MQTT_PASSWD "Consulte el tutorial de contraseña anterior, genere con la herramienta. Si no entiende el tutorial, vea abajo del artículo"
#define ALINK_BODY_FORMAT "{\"id\":\"ESP8266\",\"version\":\"1.0\",\"method\":\"thing.event.property.post\",\"params\":%s}"
#define ALINK_TOPIC_PROP_POST "/sys/" PRODUCT_KEY "/" DEVICE_NAME "/thing/event/property/post"
unsigned long lastMs = 0;
float RH,T,RH_sum,T_sum;
unsigned char count=0;
WiFiClient espClient;
PubSubClient client(espClient);
SHTC3 mySHTC3;
void callback(char *topic, byte *payload, unsigned int length)
{
Serial.print("Message arrived [");
Serial.print(topic);
Serial.print("] ");
payload[length] = '\0';
Serial.println((char *)payload);
}
void wifiInit()
{
WiFi.mode(WIFI_STA);
WiFi.begin(WIFI_SSID, WIFI_PASSWD); // Conectar a WiFi
while (WiFi.status() != WL_CONNECTED)
{
delay(1000);
Serial.println("WiFi not Connect");
}
Serial.println("Connected to AP");
Serial.println("IP address: ");
Serial.println(WiFi.localIP());
Serial.print("espClient [");
client.setServer(MQTT_SERVER, MQTT_PORT); // Conectar al servidor MQTT después de conectar a WiFi
client.setCallback(callback);
}
void mqttCheckConnect()
{
while (!client.connected())
{
Serial.println("Connecting to MQTT Server ...");
if (client.connect(CLIENT_ID, MQTT_USRNAME, MQTT_PASSWD))
{
Serial.println("MQTT Connected!");
}
else
{
Serial.print("MQTT Connect err:");
Serial.println(client.state());
delay(5000);
}
}
}
void mqttIntervalPost()
{
char param[32];
char jsonBuf[128];
sprintf(param, "{\"CurrentTemperature\":%f}",T_sum/count);
sprintf(jsonBuf, ALINK_BODY_FORMAT, param);
Serial.println(jsonBuf);
boolean d = client.publish(ALINK_TOPIC_PROP_POST, jsonBuf);
if(d){
Serial.println("publish Temperature success");
}else{
Serial.println("publish Temperature fail");
}
//https://blog.zeruns.com
sprintf(param, "{\"CurrentHumidity\":%f}",RH_sum/count);
sprintf(jsonBuf, ALINK_BODY_FORMAT, param);
Serial.println(jsonBuf);
d = client.publish(ALINK_TOPIC_PROP_POST, jsonBuf);
if(d){
Serial.println("publish Humidity success");
}else{
Serial.println("publish Humidity fail");
}
}
void errorDecoder(SHTC3_Status_TypeDef message) // La función errorDecoder imprime los resultados de "SHTC3_Status_TypeDef" de forma amigable
{
switch(message)
{
case SHTC3_Status_Nominal : Serial.print("Nominal"); break;
case SHTC3_Status_Error : Serial.print("Error"); break;
case SHTC3_Status_CRC_Fail : Serial.print("CRC Fail"); break;
default : Serial.print("Unknown return code"); break;
}
}
//https://blog.zeruns.com
void setup()
{
/* Inicializar serial para depuración */
Serial.begin(115200);
Serial.println("Demo Start");
wifiInit();
Wire.begin(D5,D6); // Inicializar la biblioteca Wire (IIC)
unsigned char i=0;
errorDecoder(mySHTC3.begin());
}
// La función loop se ejecuta una y otra vez para siempre
void loop()
{
delay(1000); // Retraso de 1000 milisegundos
SHTC3_Status_TypeDef result = mySHTC3.update();
if(mySHTC3.lastStatus == SHTC3_Status_Nominal) // Verificar si el estado del SHTC3 es normal
{
RH = mySHTC3.toPercent(); // Leer datos de humedad
T = mySHTC3.toDegC(); // Leer datos de temperatura
RH_sum+=RH;
T_sum+=T;
count+=1;
}else{
Serial.print("Update failed, error: ");
errorDecoder(mySHTC3.lastStatus); // Mostrar razón del error
Serial.println();
}
Serial.print("Humidity:"); // Imprimir "Humidity:" por el puerto serie
Serial.print(RH); // Imprimir datos de humedad por el puerto serie
Serial.print("%");
Serial.print(" Temperature:");
Serial.print(T); // Imprimir datos de temperatura por el puerto serie
Serial.println("C");
Serial.println("https://blog.zeruns.com");
if (millis() - lastMs >= 30000)
{
lastMs = millis();
mqttCheckConnect();
/* Subir datos */
mqttIntervalPost();
count=0;
RH_sum=0;
T_sum=0;
}
client.loop();
}
Modificar PubSubClient.h
Encuentre el archivo PubSubClient.h y cambie el número después de #define MQTT_MAX_PACKET_SIZE a 1024, y el número después de #define MQTT_KEEPALIVE a 60.
Tutorial para generar la contraseña
Herramienta para generar la contraseña: http://iot-face.oss-cn-shanghai.aliyuncs.com/tools.htm
Suponga que los datos de su tripleta de dispositivo son los siguientes:
Triplete del dispositivo
ProductKey = a14Xib5kdYd
DeviceName = ESP8266
DeviceSecret = oLyaKqVxtRvjH284LdhqVgVUx1UPy6zq
Parámetros para establecer la conexión MQTT, esta información es CLIENT_ID en el código, puede personalizarla
clientId = ESP8266
timestamp = 1234567890
signmethod = hmacsha1
Luego, genere el contenido de la contraseña con esta información:
clientIdESP8266deviceNameESP8266productKeya15ptdU1zhPtimestamp1234567890
Ingrese el texto plano como contenido y la clave secreta como DeviceSecret, luego haga clic en “hmac-sha1” para generar la contraseña.
Resultados
Lecturas recomendadas:
- Recomendaciones de VPS/serveur en la nube de alto rendimiento y bajo costo: https://blog.zeruns.com/archives/383.html
- Configurar un servidor de túnel de red privada con panel web: https://blog.zeruns.com/archives/397.html
- Crear un disco en la nube con Cloudreve: https://blog.zeruns.com/archives/515.html
- Cómo crear un blog personal: https://blog.zeruns.com/archives/218.html
- Beneficios para estudiantes: https://blog.zeruns.com/archives/321.html